;//	mesEX モジュール >>
#module

#deffunc m_setwait int
	mref _p,0
	wt=_p
return

#deffunc m_bcolor int,int,int
	mref _p1,0
	mref _p2,1
	mref _p3,2
	bco=_p1,_p2,_p3
return

#deffunc mesex str
	mref s,32

	;フォントの情報
	mref BMS,67
	fs=BMS.32
	col=BMS.40&0xff,BMS.40>>8&0xff,BMS.40>>16&0xff

	p=0
	x=csrx
	bx=x
	y=csry
	a="  "
	repeat
		await wt
		peek c,s,p
		if c==0 :break
		if c>127 :l=2:wpeek c,s,p:p++ :else: l=1
		p++
		if c==13 {
			x=bx
			y+fs
			peek c,s,p
			if c==10 :p++
		}
		if c==9 :x+=64-(x+1-bx\(fs*4))
		;// ---おまけ---　いらなかったら削ってください．
		if c==1 :wait 15
		if c==2 {
			pget x,y ;点の色を調べとく
			repeat
				wait 1
				stick k
				if k&(16+256) :break
				if cnt&31==0 :clm=clm^1:if clm :color rval,gval,bval: else: color col.0,col.1,col.2
				pos x,y
				mes "▼"
			loop
			color rval,gval,bval
			pos x,y
			boxf x,y,x+fs,y+fs ;消す
		}
		if c<32 :continue
		;// ---おまけ--- ここまで
		wpoke a,0,c
		;文字表示
		pos x+1,y+1
		color bco.0,bco.1,bco.2
		mes a
		pos x,y
		color col.0,col.1,col.2
		mes a
		x+=l*fs>>1
	loop
	pos x,y
	color col.0,col.1,col.2
	;pos bx,y+fs
return

#global
;//

	cls 2
	color 255,255,255

	;影の色設定
	m_bcolor 24,24,24

	m_setwait 40
	pos 100,50
	mesex "2バイト文字もOK.です．\n"
	mesex {"タブ(\\t)も\t使えます
		123\t456\t789ＡＢＣＤＥ\n"}
	mesex "色も"
	m_bcolor 0,0,128 ;影の色
	color 255,255,0 ;文字の色
	mesex "自由に"
	m_bcolor 255,0,0
	color 255,128,128
	mesex "変えられます\n"


	; // おまけ機能
	str ww
	wpoke ww,0,1
	str cl
	wpoke cl,0,2

	color 255,255,255
	pos 20,200
	mesex "おまけ機能．"
	mesex "文字データに"+ww+"ウ"+ww+"ェ"+ww+"イ"+ww+"ト"+ww+"を入れたりできます．\n"
	mesex "クリック"+cl+"も入れたりできます．"+cl+"\n"
	mes "おわり"
	mesex cl