////////////////////////////////////////////////////////////////////
//	分数計算モジュール
////////////////////////////////////////////////////////////////////

#module "bunsuu"
#deffunc b_print val
	mref _p1,16
	x=csrx
	y=csry
	mref BMS,67
	fy=BMS.32
	s=""+_p1.0
	strlen l,s
	s=""+_p1.1
	strlen l2,s
	if l2>l :l=l2
	l=l+1/2

	if _p1.1!=1 {
		pos x+4,y
		mes _p1.0
		line x,y+fy,fy*l+x,y+fy
		pos x+4,y+fy
		mes _p1.1
		pos fy*l+4+x,y
	}else{
		pos x+4,fy/2+y
		mes _p1.0
		pos fy*l+4+x,y
	}
return

#deffunc b_mes str
	mref _p1,32
	x=csrx
	y=csry
	mref BMS,67
	fy=BMS.32
	pos x,fy/2+y
	mes  _p1
	strlen l,_p1
	pos l*fy>>1+x,y
return


#deffunc b_yakubunn val
	mref _p1,16
	a1=_p1.0
	a2=_p1.1

	repeat
		t=a1-(a1/a2*a2)
		if t=0 :break // OK
		a1=a2
		a2=t
	loop
	_p1.0=_p1.0/a2
	_p1.1=_p1.1/a2
return

#deffunc b_add val,val
	mref _p1,16
	mref _p2,17
	a1=_p1.1
	a2=_p2.1

	if a1<a2 :a1=a1^a2:a2=a2^a1:a1=a1^a2
	repeat
		t=a1-(a1/a2*a2)
		if t=0 :break // OK
		a1=a2
		a2=t
	loop
	_p1.0=_p1.0*_p2.1/a2+(_p2.0*_p1.1/a2)
	_p1.1=_p1.1/a2*_p2.1
return

#deffunc b_sub val,val
	mref _p1,16
	mref _p2,17
	a1=_p1.1
	a2=_p2.1

	if a1<a2 :a1=a1^a2:a2=a2^a1:a1=a1^a2
	repeat
		t=a1-(a1/a2*a2)
		if t=0 :break // OK
		a1=a2
		a2=t
	loop
	_p1.0=_p1.0*_p2.1/a2-(_p2.0*_p1.1/a2)
	_p1.1=_p1.1/a2*_p2.1
return


#deffunc b_mul val,val
	mref _b1,16
	mref _b2,17

	;b_yakubunn _b1
	;b_yakubunn _b2

	_b1.0=_b1.0*_b2.0
	_b1.1=_b1.1*_b2.1

	b_yakubunn _b1
return


#deffunc b_div val,val
	mref _b1,16
	mref _b2,17

	;b_yakubunn _b1
	;b_yakubunn _b2

	_b1.0=_b1.0*_b2.1
	_b1.1=_b1.1*_b2.0

	b_yakubunn _b1
return

#deffunc b_inv val
	mref _b1,16
	//一時変数を使わず入れ替え(^^;
	_b1.0=_b1.0^_b1.1
	_b1.1=_b1.1^_b1.0
	_b1.0=_b1.0^_b1.1
return

#deffunc b_atob val,str
	mref _p1,16
	mref _p2,33
	sdim s1,64
	sdim s2,64
	getstr s1,_p2,0,'/'
	if stat=='/' {
		peek s2,_p2,strsize
	}else{
		getstr s1,_p2,0,'.'
		peek s2,_p2,strsize
		s1+=s2
		strlen l,s2
		s2="1000000000000000000000"
		poke s2,l+1,0
	}
	if s2=="" :s2="1"
	_p1.0=0+s1
	_p1.1=0+s2

return

#global
////////////////////////////////////////////////////////////////////
	//  1/2.56 / 128/256 = ?

	b_atob a,"2.56"
	b_atob b,"128/256"

	b_inv a ;逆数

	b_print a

	b_mes "/"

	b_print b

	b_mes "="

	b_div a,b ;a/b
	b_print a

stop